Файл:Euclidian and non euclidian geometry.png
Эх файл (4,000 × 1,500 пиксел, файлын хэмжээ: 128 КБ, MIME төрөл: image/png)
Энэ файл нь Wikimedia Commons-нх бөгөөд бусад төслүүд үүнийг хэрэглэх боломжтой. Доор файлын тайлбарын хуудсан дээрх тайлбарыг оруулсан байгаа:
Shows three "blocks" with varying surfaces, whereon a point and som lines are "drawn" to demonstrate
- euclidian
- elliptical and
- hyperbolic geometry
To be exact, the hyperbolic surface was approximated using a chunk of the "inside" of a torus - this may not be perfectly accurate, but apparently it "looks right" in this illustration. :-)
Rendered using POV-Ray (see http://www.povray.org) and the scene description "code" below, then cropped and "numbered" using a graphics software package.
Povray source code |
---|
/*
====================================================================
Surfaces demonstrating euclidian, elliptical and hyperbolic geometry
--------------------------------------------------------------------
Created by Søren Peo Pedersen - see my user page at
http://da.wikipedia.org/wiki/Bruger:Peo
====================================================================
*/
// Macro for texture with background pattern, lines, and point "marker"
#macro SurfaceDrawing (
Point, // Position vector: Location of white point
RefLineMove, // Transformation: Where to place the yellow reference line
Lines // Object that renders the blue line(s)
)
#local BasePattern=pigment { // The underlying, dark grey checkerboard pattern
checker
color rgb 0.4
color rgb 0.6
scale <1,1000,1>
}
#local SP1 = pigment { // Checkerboard pattern with yellow "reference line" added
object {box {<-.07,-10,-10>,<.07,10,10> transform{RefLineMove}}
pigment {BasePattern}
pigment {color rgb <1,.8,.3>}
}
}
#local SP2 = pigment { // Checkerborad + yellow line with user-defined (blue) lines added
object {Lines
pigment {SP1}
pigment {color rgb <.6,.8,1>}
}
}
#local SP3 = pigment { // Checkerboard + lines with whit point "marker" added
object {
sphere { Point, .2 }
pigment {SP2}
pigment {color rgb 1}
}
}
pigment { // Definition of pigment, confined to a box slightly smaller than the "blocks"
boxed // to make the lines and point only appear on the top of the blocks
pigment_map {
[0.0000 BasePattern scale .5 translate <0,-1,0>]
[0.0001 BasePattern scale .5 translate <0,-1,0>]
[0.0001 SP3 scale .5 translate <0,-1,0>]
[1.0000 SP3 scale .5 translate <0,-1,0>]
}
scale <2,2,2> translate <0,2,0>
}
finish {ambient .7 diffuse .3}
#end // End of macro
plane {<0,1,0>,0 // White "tabletop" to receive shadows of the blocks (helps visualisation)
pigment {color rgb 1}
finish {ambient .8 diffuse .5}
}
box {<-2,0,-2>,<2,2,2> // Demonstrating euclidean geometry
texture {
SurfaceDrawing(<-.3,2,0>,
transform {rotate <0,35,0> translate <.3,0,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,35,0> translate <-.3,0,0>}
)
}
rotate <0,-20,0>
translate <-6,0,0>
}
intersection { // Demonstrating elliptical, or "Riemann", geometry
box {<-2,0,-2>,<2,5,2>}
sphere {<0,0,0>,2.8285}
texture {
SurfaceDrawing(<.65,2.45,1.25>,
transform {rotate <0,5,0> rotate <-45,35,0>},
box {<-.07,-10,-10>,<.07,10,10> rotate <0,-4,0> rotate <-45,35,0>}
)
}
rotate <0,-20,0>
translate <0,0,0>
}
intersection { // Demonstrating hyperbolic geometry
box {<-2,0,-2>,<2,4,2>}
torus {7.03,5 rotate <90,90,0> translate <0,4,0>}
texture {
SurfaceDrawing(<0,2.3,1>,
transform {rotate <0,90,0> rotate <-40,0,0> translate <0,4,0>},
merge {
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,85,0> rotate <-30,0,0> translate <0,4,0>
}
box {<-.07,-10,-10>,<.07,10,10>
rotate <0,95,0> rotate <-30,0,0> translate <0,4,0>
}
}
)
}
rotate <0,-20,0>
translate <6,0,0>
}
camera { // Viewpoint
location <0,2100,-800>
look_at <.5,0,0>
angle .47
}
light_source {<-50,200,-100> color rgb 1.5} // Illumination
|
Энэхүү баримт бичгийг GNU Free Documentation License, Хувилбарын нөхцлийн дагуу хуулах, түгээх болон/эсвэл өөрчлөх зөвшөөрөл олгосон. 1.2 эсвэл Чөлөөт програм хангамжийн сангаас нийтэлсэн дараагийн хувилбар; Инвариант хэсэггүй, нүүрэн талын текстгүй, арын хавтастай текстгүй. Лицензийн хуулбарыг GNU Free Documentation License гэсэн хэсэгт оруулсан болно.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
Энэ файл нь Creative Commons Attribution-Share Alike 3.0 Unported лицензтэй байна. | ||
| ||
This licensing tag was added to this file as part of the GFDL licensing update.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue |
Items portrayed in this file
depicts англи
copyright status англи
copyrighted англи
media type англи
image/png
Файлын түүх
Огноо/цаг дээр дарж тухайн үеийнх нь файлын байдлыг харна уу.
Огноо/Цаг | Жижиг зураг | Хэмжээ | Хэрэглэгч | Тайлбар | |
---|---|---|---|---|---|
одоогийн | 05:47, 6 Долоодугаар сар 2015 | 4,000 × 1,500 (128 КБ) | wikimediacommons>Cmdrjameson | Compressed with pngout. Reduced by 66kB (34% decrease). |
Файлын хэрэглээ
Дараах хуудас уг файлтай холбогдсон байна:
Зургийн тухай мэдээлэл
Энэ файланд бодвол дижитал аппарат эсвэл сканнераас нэмэгдсэн нэмэлт мэдээлэл байна.
Хэрэв энэ файл анхныхаа байдлаас өөрчлөгдсөн бол зарим мэдээлэл нь одоогийн хувилбартайгаа нийцэхгүй байж магадгүй.
Зургийн хөндлөн чанар | 35.43 dpc |
---|---|
Зургийн босоо чанар | 35.43 dpc |
Файлыг өөрчлилсөн огноо ба цаг | 19:09, 4 Наймдугаар сар 2012 |